【VBScript】簡単に使える！ログ出力部品

main.vbs（呼び出し側）

Option Explicit

' ログの出力先
Const LOG_PATH = "C:\workspace\VBScript"
' ログのファイル名
Const LOG_NAME = "main.log"

' ファイルシステムオブジェクトの作成
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

' 関数の読み込み
Execute fso.OpenTextFile("function.vbs").ReadAll()

' ファイルシステムオブジェクトの破棄
Set fso = Nothing

' ログ出力部品の呼び出し
Call WriteLog("出力するメッセージ１", LOG_INFO)
Call WriteLog("出力するメッセージ２", LOG_ERROR)
Call WriteLog("出力するメッセージ３", LOG_INFO)

function.vbs（呼び出される側）

Option Explicit

' ログレベル(INFO)
Const LOG_INFO = "INFO"
' ログレベル(ERROR)
Const LOG_ERROR = "ERROR"

' ログ出力
Function WriteLog(Byval msg, Byval level)

	Dim strDate, strTime, header
	strDate = Date()
	strTime = Time()
	
	' 定数定義チェック
	If(LOG_PATH = "" Or LOG_NAME = "")Then
		WScript.Echo("ログ出力関数向け定数が定義されていません。")
		WScript.Quit
	End If

	' ファイルシステムオブジェクトの作成
	Dim fso
	Set fso = CreateObject("Scripting.FileSystemObject")

	' テキストファイルのオープン(追記モード)
	Dim logFile
	Set logFile = fso.OpenTextFile(LOG_PATH & "\" & Replace(LOG_NAME , ".", "_" & Replace(strDate, "/", "") & "."), 8, True)

	' ヘッダーの作成
	header = "[" & strDate & " " & strTime & "][" & level & "]"

	' ログの書き込み
	logFile.WriteLine(header & msg)

	' ログのクローズ
	logFile.Close

	' ファイルシステムオブジェクトの破棄
	Set fso = Nothing

End Function