【VBScript】VirtualBox向け仮想マシンの一括起動スクリプト

Option Explicit

' 起動対象仮想マシンリスト
Const VM_LIST = "VBoxAutoStart.conf"
' 起動処理待ち合わせ時間(秒)
Const INTERVAL = 300
' ログの出力先
Const LOG_PATH = "C:\workspace\VBScript"
' ログのファイル名
Const LOG_NAME = "VBoxAutoStart.log"
' VirtualBoxインストールパス
Const VB_PATH = "C:\Program Files\Oracle\VirtualBox"

' 起動対象の仮想マシン
Dim vmList()
' 仮想マシンの起動情報
Dim vmStatus()
' 起動中の仮想マシン
Dim vmRunning()

' ファイルシステムオブジェクトの作成
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

' 関数の読み込み
Execute fso.OpenTextFile("function.vbs").ReadAll()

' ファイルシステムオブジェクトの破棄
Set fso = Nothing

Call WriteLog("仮想マシンの起動スクリプトの開始。", LOG_INFO)

' 起動対象の仮想マシンを取得
Call GetVMList()

' 仮想マシン起動状態の取得
Call GetVMStatus()

' 起動中の仮想マシン名の取得
Call GetVMRunning()

' 仮想マシンの起動
Call StartVM()

Call WriteLog("仮想マシンの起動スクリプトの終了。", LOG_INFO)

WScript.Quit

' 起動対象仮想マシンの取得関数
Function GetVMList()

	' 起動対象の仮想マシンの定義ファイル読み込み行
	Dim line

	' 起動対象の仮想マシンの定義ファイル読み込み行数
	Dim lineNum
	lineNum = 0

	' ファイルシステムオブジェクトの作成
	Dim fso
	Set fso = CreateObject("Scripting.FileSystemObject")

	' ファイルを読み取り専用で読み込み
	Dim stream
	Set stream  = fso.OpenTextFile(VM_LIST, 1)

	' １行ずつファイルを読み込む
	Do Until stream.AtEndOfStream
		line = stream.ReadLine
		Call WriteLog("起動対象仮想マシン名：" & line, LOG_INFO)
		lineNum = lineNum + 1
		ReDim Preserve vmList(lineNum - 1)
		vmList(lineNum - 1) = line
	Loop

	' テキストファイルを閉じる
	stream.Close
	Set stream = Nothing

	' ファイルシステムオブジェクトの破棄
	Set fso = Nothing

End Function

' 仮想マシンの起動状態確認
Function GetVMStatus()

	' WSH関連オブジェクト
	Dim objShell, objExec

	' 起動状態読み込み行
	Dim line

	' 起動状態読み込み行数
	Dim lineNum
	lineNum = 0

	' コマンドの作成
	Dim cmd
	cmd = """" & VB_PATH & "\VBoxManage"" list runningvms"
	Call WriteLog("実行コマンド：" & cmd, LOG_INFO)

	' WSHオブジェクトの作成
	Set objShell = CreateObject("WScript.Shell")

	' Windowsコマンドの実行
	Set objExec = objShell.Exec("cmd /c " & cmd)

	' 実行結果の確認
	Do Until objExec.StdOut.AtEndOfStream
		line = objExec.StdOut.ReadLine
		lineNum = lineNum + 1
		ReDim Preserve vmStatus(lineNum - 1)
		vmStatus(lineNum - 1) = line
	Loop

	' WSH関連オブジェクトの破棄
	Set objExec = Nothing
	Set objShell = Nothing

End Function

' 起動中の仮想マシン名の取得
Function GetVMRunning()

	' 仮想マシンの起動情報
	Dim buf
	' 仮想マシン名
	Dim vmName
	' 配列処理行
	Dim lineNum
	lineNum = 0

	For Each buf In vmStatus
		vmName = Split(buf, """ ")
		lineNum = lineNum + 1
		ReDim Preserve vmRunning(lineNum - 1)
		vmRunning(lineNum - 1) = Right(vmName(0), Len(vmName(0)) - 1)
	Next

End Function

' 起動していない仮想マシンの起動
Function StartVM()

	' 起動対象の仮想マシン
	Dim target
	' 起動中の仮想マシン
	Dim running
	' 仮想マシンの起動フラグ
	Dim isStart
	' WSHオブジェクト
	Dim objShell

	' WSHオブジェクトの作成
	Set objShell = CreateObject("WScript.Shell")

	For Each target In vmList
		isStart = False
		For Each running In vmRunning
			' 起動対象の仮想マシンが既に起動している場合は処理をしない
			If(target = running)Then
				Call WriteLog("仮想マシン【" & target & "】は起動済みです。", LOG_INFO)
				isStart = True
				Exit For
			End If
		Next

		' 仮想マシンが停止している場合は起動する
		If Not(isStart)Then
			Call WriteLog("仮想マシン【" & target & "】の起動開始。", LOG_INFO)

			' コマンドの作成
			Dim cmd
			cmd = """" & VB_PATH & "\VBoxManage"" startvm " & target & " --type headless"
			Call WriteLog("実行コマンド：" & cmd, LOG_INFO)
			' Windowsコマンドの実行
			Call objShell.Exec("cmd /c " & cmd)
			WScript.Sleep(INTERVAL * 1000)
			Call WriteLog("仮想マシン【" & target & "】の起動終了。", LOG_INFO)
		End If
	Next

	' WSH関連オブジェクトの破棄
	Set objShell = Nothing

End Function

ゲストマシン１
ゲストマシン２

[2023/03/19 7:23:04][INFO]仮想マシンの起動スクリプトの開始。
[2023/03/19 7:23:04][INFO]起動対象仮想マシン名：ゲストマシン１
[2023/03/19 7:23:04][INFO]起動対象仮想マシン名：ゲストマシン２
[2023/03/19 7:23:04][INFO]実行コマンド："C:\Program Files\Oracle\VirtualBox\VBoxManage" list runningvms
[2023/03/19 7:23:04][INFO]仮想マシン【ゲストマシン１】の起動開始。
[2023/03/19 7:23:04][INFO]実行コマンド："C:\Program Files\Oracle\VirtualBox\VBoxManage" startvm ゲストマシン１ --type headless
[2023/03/19 7:23:34][INFO]仮想マシン【ゲストマシン１】の起動終了。
[2023/03/19 7:23:34][INFO]仮想マシン【ゲストマシン２】の起動開始。
[2023/03/19 7:23:34][INFO]実行コマンド："C:\Program Files\Oracle\VirtualBox\VBoxManage" startvm ゲストマシン２ --type headless
[2023/03/19 7:24:04][INFO]仮想マシン【ゲストマシン２】の起動終了。
[2023/03/19 7:24:04][INFO]仮想マシンの起動スクリプトの終了。