【TeraTermマクロ】1ファイルで文字・背景色の変更＋自動ログイン

以前、TeraTermでの自動ログインマクロを作成したので、今回は文字と背景色も変更出来るように機能を拡張しました。
設定ファイルを個別に用意する方法は良く見つかるので、ここではマクロ内に設定を埋め込み、１ファイルに纏める方法をご紹介します。

ソースコード
実行イメージ

ソースコード

以下のソースコードをテキストエディタに貼り付けて保存します。
＊拡張子は「.ttl」として下さい。
下記の項目については環境に合わせて修正して下さい。
・HOST：接続先サーバのIPアドレスを指定
・USER：接続先サーバにログインするユーザ名を指定
・PASS：[USER]に対応するパスワードを指定
・COLOR：文字と背景の色をRGBで指定（例では黒板のような色合いになっています。）
・DEFAULT_INI：TeraTermをインストールした際に自動で作成される設定ファイルのフルパスを指定

; 接続先
HOST = '***.***.***.***'
; ログインユーザ
USER = '****'
; ログインパスワード
PASS = '****'
; 色設定(文字のRGB,背景のRGB)
COLOR='216,216,216,0,64,64'
; TeraTermの設定ファイル
DEFAULT_INI = 'C:\Program Files (x86)\teraterm\TERATERM.INI'

; マクロファイル名.iniの作成
strlen param1
exlength = result - 3
strremove param1 exlength 4
getdir TEMP_INI
strconcat TEMP_INI '\'
strconcat TEMP_INI param1
strconcat TEMP_INI '.ini'
fileopen buf DEFAULT_INI 0 1
fileopen tmp TEMP_INI 0

:freadloop
filereadln buf line
if result then
	goto breakloop
endif
strsplit line '=' 9

; 文字色・背景色変更
strcompare groupmatchstr1 "VTColor"
if result = 0 then
	config = 'VTColor='
	strconcat config COLOR
	filewriteln tmp config
endif

if result != 0 then
	filewriteln tmp line
endif
goto freadloop

:breakloop
fileclose buf
fileclose tmp

; 接続処理
cmd = HOST
strconcat cmd ' /ssh /2 /auth=PASS /user='
strconcat cmd USER
strconcat cmd ' /passwd='
strconcat cmd PASS
strconcat cmd ' /F='
strconcat cmd TEMP_INI
connect cmd

; 一時的に作成した設定ファイルの削除
filedelete TEMP_INI

リンク